100 hires 0,1:n=20
110 FOR i=0 TO n STEP 2
120  s_circle 160,100,i*8,(20-i)*5,1
130 END FOR i
140 :
10260 DEFine PROCedure s_circle(x,y,a,b,z)
10270  LOCal nl:nl=1E-3
10280  INK f_vari((z))
10290  IF ABS(a)>nl AND ABS(b)>nl THEN 
10300   CIRCLE x,200-y,b,a/b,0
10310   RETurn 
10320  END IF 
10330  IF ABS(a)<nl THEN 
10340   LINE x,200-y-b TO x,200-y+b
10350   RETurn 
10360  END IF 
10370  IF ABS(b)<nl THEN 
10380   LINE x-a,200-y TO x+a,200-y
10390   RETurn 
10400  END IF 
10410 END DEFine s_circle
10420 :
15000 DEFine PROCedure hires(etu%,taus%)
15010  MODE 8
15020  etuvari%=etu%:taustavari%=taus%
15030  WINDOW 512,256,0,0:PAPER 1:CLS
15040  WINDOW 430,200,41,16
15050  PAPER f_varikoodi((taus%)):CLS
15060  INK f_varikoodi((etu%))
15070  SCALE 200,0,0
15080 END DEFine hires
15090 :
15100 DEFine FuNction f_varikoodi(vari%)
15110  LOCal varil:varil=vari%
15120  SELect ON varil
15130   = 0:RETurn 0  :REMark black
15140   = 1:RETurn 7  :REMark white
15150   = 2:RETurn 2  :REMark red
15160   = 3:RETurn 5  :REMark cyan
15170   = 4:RETurn 202:REMark purple
15180   = 5:RETurn 4  :REMark green
15190   = 6:RETurn 1  :REMark blue
15200   = 7:RETurn 6  :REMark yellow
15210   = 8:RETurn 226:REMark orange
15220   = 9:RETurn 208:REMark brown
15230   =10:RETurn 234:REMark light red
15240   =11:RETurn 250:REMark grey 1
15250   =12:RETurn 248:REMark grey 2
15260   =13:RETurn 220:REMark light green
15270   =14:RETurn 5:REMark light blue
15280   =15:RETurn 206:REMark grey 3
15290   =REMAINDER :RETurn 0
15300  END SELect 
15310 END DEFine f_varikoodi
15320 :
15330 DEFine FuNction f_vari(tapa%)
15340  LOCal tapal:tapal=tapa%
15350  SELect ON tapal
15360   =0:RETurn f_varikoodi((taustavari%))
15370   =1:RETurn f_varikoodi((etuvari%))
15380   =REMAINDER :RETurn f_varikoodi((etuvari%))
15390  END SELect 
15400 END DEFine f_vari
15410 :
31000 DEFine PROCedure reset(i)
31010  LOCal il:MODE i
31020  WINDOW 513,256,0,0:PAPER 0:CLS
31030  OPEN#2,con_:WINDOW#2,448,200,32,16
31040  PAPER#2,1:INK#2,7
31050  WINDOW#0,448,40-(i=4),32,216+(i=4)
31060  WINDOW 448+8*(i=4),200+2*(i=4),32-4*(i=4),16-(i=4)
31070  PAPER 2*(i=8):BORDER (i=4),4*(i=4)
31080  FOR il=0,1,2:CSIZE#il,(i=4)+2*(i=8),0:END FOR il
31090  PAPER#0,0:INK#0,7-3*(i=0):INK 7:CLS
31100  SCALE 100,0,0:FILL 0
31110 END DEFine reset
